Complete Linux/Complete Linux.iso/docs/devel/tcl/itcl1_31.z/itcl1_31/tcldev/itcl-1.3/tests/inherit.test

Text File | 1993-10-15 | 5.1 KB | 194 lines

#
# Tests for inheritance and scope handling
# ----------------------------------------------------------------------
#   AUTHOR:  Michael J. McLennan       Phone: [phone]
#            AT&T Bell Laboratories   E-mail: aluxpo![e-mail]
#
#     SCCS:  @(#)inherit.test    1.5 (10/14/93)
# ----------------------------------------------------------------------
#            Copyright (c) 1993  AT&T  All Rights Reserved
# ======================================================================

# ----------------------------------------------------------------------
#  MULTIPLE BASE-CLASS ERROR DETECTION
# ----------------------------------------------------------------------
test {Cannot inherit from the same base class more than once} {
    catch "VirtualErr" errmsg
    set errmsg
} {
    $result == {error while autoloading "VirtualErr": class "VirtualErr" inherits base class "Foo" more than once:
  VirtualErr->Mongrel->FooBar->Foo
  VirtualErr->Foo
  VirtualErr->BarFoo->Foo}
}

# ----------------------------------------------------------------------
#  CONSTRUCTION
# ----------------------------------------------------------------------
test {Constructors should be invoked implicitly} {
    set WATCH ""
    concat [Mongrel m] / $WATCH
} {
    $result == "m / Mongrel FooBar Foo Bar Geek"
}

test {Initialization of shadowed variables works properly} {
    concat [m info public blit -value] / [m info public Foo::blit -value]
} {
    $result == "nonnull / <undefined>"
}

# ----------------------------------------------------------------------
#  PUBLIC VARIABLES
# ----------------------------------------------------------------------
test {Inherited "config" method works on derived classes} {
    m config -blit xyz -Foo::blit pdq
} {
    $result == "Mongrel::blit Foo::blit"
}

test {Inherited "config" method works on derived classes} {
    m config -blit xyz -Foo::blit pdq
    concat [m info public blit -value] / [m info public Foo::blit -value]
} {
    $result == "xyz / pdq"
}

# ----------------------------------------------------------------------
#  INHERITANCE INFO
# ----------------------------------------------------------------------
test {Info: class} {
    m info class
} {
    $result == "Mongrel"
}

test {Info: inherit} {
    m info inherit
} {
    $result == "FooBar Geek"
}

test {Info: heritage} {
    m info heritage
} {
    $result == "Mongrel FooBar Foo Bar Geek"
}

test {Built-in "isa" method} {
    set status 1
    foreach c [m info heritage] {
        set status [expr {$status && [m isa $c]}]
    }
    set status
} {
    $result == 1
}

test {Built-in "isa" method} {
    m isa Watermelon
} {
    $result == 0
}

# ----------------------------------------------------------------------
#  SCOPE MANIPULATION
# ----------------------------------------------------------------------
test {commands normally execute in the scope of their class} {
    m Foo::do {info class}
} {
    $result == "Foo says 'Foo'"
}

test {"virtual" command moves scope to most specific class} {
    m Foo::do {virtual info class}
} {
    $result == "Foo says 'Mongrel'"
}

test {"previous" command moves scope upward in hierarchy} {
    m do {virtual previous info class}
} {
    $result == "Foo says 'FooBar'"
}

test {"previous" command can be chained} {
    m do {virtual previous previous info class}
} {
    $result == "Foo says 'Foo'"
}

# ----------------------------------------------------------------------
#  METHOD INVOCATION
# ----------------------------------------------------------------------
test {Simple method names are assigned based on heritage} {
    m do {concat "$this ([virtual info class]) at scope [info class]::"}
} {
    $result == "Foo says 'm (Mongrel) at scope Foo::'"
}

test {Explicit scoping can be used to reach shadowed members} {
    m Geek::do {concat "$this ([virtual info class]) at scope [info class]::"}
} {
    $result == "Geek says 'm (Mongrel) at scope Geek::'"
}

test {Methods execute in local scope of class, e.g., Foo::do} {
    m config -blit abc -Foo::blit def
    m Foo::do {set blit xyz}
    concat [m info public blit -value] / [m info public Foo::blit -value]
} {
    $result == "abc / xyz"
}

# ----------------------------------------------------------------------
#  DESTRUCTION
# ----------------------------------------------------------------------
test {Destructors should be invoked implicitly} {
    set WATCH ""
    concat [m delete] / $WATCH
} {
    $result == "/ Mongrel Geek Bar Foo FooBar"
}

# ----------------------------------------------------------------------
#  OBJECT INFO
# ----------------------------------------------------------------------
foreach obj [itcl_info objects] {
    $obj delete
}
Mongrel m
FooBar fb
Foo f
Geek g

test {Object queries can be restricted by object name} {
    itcl_info objects f*
} {
    [test_cmp_lists $result {f fb}]
}

test {Object queries can be restricted to specific classes} {
    itcl_info objects -class Foo
} {
    $result == "f"
}

test {Object queries can be restricted by object heritage} {
    itcl_info objects -isa Foo
} {
    [test_cmp_lists $result {m f fb}]
}

test {Object queries can be restricted by object name / specific classes} {
    itcl_info objects f* -class Foo
} {
    $result == "f"
}

test {Object queries can be restricted by object name / object heritage} {
    itcl_info objects f* -isa Foo
} {
    [test_cmp_lists $result {f fb}]
}